home *** CD-ROM | disk | FTP | other *** search
/ HPAVC / HPAVC CD-ROM.iso / pc / RGASM.RAR / ASMCODE.EXE / CHAPT9 / PARKING.ASM < prev    next >
Encoding:
Assembly Source File  |  1994-08-27  |  6.2 KB  |  121 lines
  1. ; 
  2. ;       Program Parking ( Chapter 9 )
  3. ;
  4.     page    55,132
  5. .model  tiny 
  6. .stack
  7. .data
  8. CR      equ     00Dh            ; Carriage return code
  9. LF      equ     00Ah            ; Line feed code
  10. EscScan equ     001h            ; Scan code for ESC key
  11. EndMsg  equ     024h            ; Dollar sign - end of message for DOS service
  12. Ten     db      10              ; Constant to convert binary to string
  13. StMsg   db      CR,LF,LF,'The Hard Disk Parking utility      06.04.1992'
  14.     db      '     Version 1.4', CR , LF
  15.     db      'Copyright (C) 1992 V.B.Maljugin,     Voronezh, Russia',CR,LF,LF
  16. Ndrives db      '0'
  17.     db      ' hard disk drive(s) found', CR, LF, EndMsg
  18. PrkMsg  db      CR,LF,'Heads of the hard disk drive '
  19. DrNum1  db      '/'
  20.     db      ' have been positioned at the cylinder ',EndMsg
  21. FinMsg  db      CR,LF,LF
  22.     db      'Turn off the power or press the ESC key to return to DOS'
  23.     db      CR,LF,LF,EndMsg
  24. LandZone        dw      0
  25. Drive           db      7Fh
  26. HexTab  db      '0' , '1' , '2', '3', '4' , '5', '6' , '7'
  27.     db      '8' , '9' , 'A', 'B', 'C' , 'D', 'E' , 'F'
  28.  
  29. .code                                   ; The CODE segment stars here
  30. .startup                                ; This is a standard prologue
  31.     org     100h
  32. ;===    Getting the number of drives installed
  33.     mov     cx,0                    ; Clear CX
  34.     mov     es,cx                   ; ES points to segment 0000h
  35.     mov     cl,es:[475h]            ; Get number of drives from BIOS area
  36.     add     Ndrives,cl              ; Form text for number of drives
  37. ;===    Outputting the initial message
  38.     lea     dx,StMsg                ; Address of message into DX
  39.     mov     ah,09                   ; Function 09h - output text string
  40.     int     21h                     ; Dos service call
  41. ;===    Checking whether there are drives to be processed
  42. ToNext: 
  43.     add     DrNum1,1                ; Text for message about parking
  44.     add     Drive,01h               ; Take the next disk drive 1    
  45.     mov     al,DrNum1               ; Load current drive number (char)
  46.     cmp     al,Ndrives              ; Compare it with the number of drives
  47.     jb      ProcDrives              ; If not all the drives - continue
  48.     jmp     Finish                  ; Otherwise proceed to the exiting
  49. ProcDrives:             ;===  Processing the current drive starts from here  ===
  50. ;===    Recalibrate the current drive
  51.     mov     ah,11h                  ; Function 11h - recalibrate drive
  52.     mov     dl,Drive                ; DL - drive number (80h for drive 1)
  53.     int     13h                     ; BIOS disk service call
  54.     jnc     DriveOK                 ; If recalibration successful - continue
  55.     jmp     ToNext                  ; If failed, proceed to the next drive
  56. ;===    Getting the maximum number of cylinders
  57. DriveOK:
  58.     mov     ah,08                   ; Function 08 - Get drive parameter
  59.     int     13h                     ; BIOS disk service
  60.     mov     al,ch                   ; Low part of maximum cylinder number
  61.     shl     cx,1                    ; Bit 7 of CL into bit 0 of CH
  62.     shl     cx,1                    ; Bits 6,7 of CL into bits 0,1 of CH
  63.     and     ch,3                    ; Bits 0,1 of CH will be used
  64.     mov     ah,ch                   ; Form maximum number of cylinder
  65.     add     ax,2                    ; One cylynder farther maximum
  66.     cmp     ax,1023                 ; Is it above 1023?
  67.     jle     le1023                  ; If not - process this number
  68. ;===    Replace the number of cylinders that is greater than 1023 with 1023     
  69.     mov     ax,1023                 ; If it is so - replace it with 1023
  70. ;===    Prepare input parameters for positioning the heads      
  71. le1023:                                 ;
  72.     mov     LandZone,ax             ; Store Landzone to be output
  73.     mov     ch,ah                   ; CH - low byte of cylinder number,
  74.     shr     cx,1                    ; Shift bits 0 and 1 of CH into
  75.     shr     cx,1                    ;    bits 6 and 7 of CL (high bits)
  76.     mov     ch,al                   ; Low bits of LandZone
  77. ;===    Positioning the heads
  78.     mov     ah,0Ch                  ; Function 0Ch - heads positioning
  79.     mov     dh,0                    ; Head number = 0
  80.     mov     dl,Drive                ; Drive number (80h for drive 0)
  81.     int     13h                     ; BIOS disk service call
  82. ;===    Outputting the message "parked at ..."
  83.     lea     dx,PrkMsg               ; Addres of message "parked" into DX
  84.     mov     ah,09                   ; Function 09h - output text string
  85.     int     21h                     ; Dos service call
  86. ;===    Convert the number of landing cylinder into text for printing
  87.     mov     ax,LandZone             ; Place number to be printed into AX.
  88.     mov     cx,0                    ; Initial value for counter of digits
  89. NexDiv:
  90.     div     byte ptr Ten            ; Division the number by 10. Result in
  91.                     ;    AL register and remainder in AH.
  92.     push    ax                      ; Push Remainder into stack.
  93.     mov     ah,0
  94.     inc     cx                      ; Increase counter
  95.     cmp     al,0                    ; Check if result is zero
  96.     jne     NexDiv                  ; If not, get the next digit
  97. ;===    Outputting the number of landing zone   
  98.     mov     ah,02h                  ; Function 02h - output symbol
  99. OutSym: pop     dx                      ; Pop next digit of result
  100.     mov     dl,dh                   ; Cypher into DL for output
  101.     add     dl,30h                  ; Convert it to character
  102.     int     21h                     ; Output it using DOS service
  103.     loop    OutSym                  ; Proceed to the next digit
  104.     
  105.     jmp     ToNext                  ; Proceed to the next drive processing
  106.     
  107. Finish:
  108.     lea     dx,FinMsg               ; Addres of message into DX
  109.     mov     ah,09                   ; Function 09h - output text string
  110.     int     21h                     ; Dos service call
  111. ;===    Waiting for a key pressed
  112. WaitKey:
  113.     mov     ax,0                    ; Function 00h - read character from keyboard
  114.     int     16h                     ; BIOS keyboard service call
  115.     cmp     ah,EscScan              ; Is the ESC key pressed?
  116.     jne     WaitKey                 ; If not - Wait for next key pressing
  117. ;===    Exit to DOS if necessary
  118.     mov     ax,4C00h                ; Function 4Ch - terminate process
  119.     int     21h                     ; DOS service call
  120.     end
  121.